Keith Hair

Aug 04 2008

Find Intersection Point of two lines in AS3

Posted by: Keith H in ActionScript 3, Flash 9, tags: Intersection

The intersection Point of two lines is useful to know. This is a function to find it in AS3.

//---------------------------------------------------------------
//Checks for intersection of Segment if as_seg is true.
//Checks for intersection of Line if as_seg is false.
//Return intersection of Segment "AB" and Segment "EF" as a Point
//Return null if there is no intersection
//---------------------------------------------------------------
function lineIntersectLine(A:Point,B:Point,E:Point,F:Point,as_seg:Boolean=true):Point
{
	var ip:Point;
	var a1:Number;
	var a2:Number;
	var b1:Number;
	var b2:Number;
	var c1:Number;
	var c2:Number;
 
	a1= B.y-A.y;
	b1= A.x-B.x;
	c1= B.x*A.y - A.x*B.y;
	a2= F.y-E.y;
	b2= E.x-F.x;
	c2= F.x*E.y - E.x*F.y;
 
	var denom:Number=a1*b2 - a2*b1;
	if(denom == 0){
		return null;
	}
	ip=new Point();
	ip.x=(b1*c2 - b2*c1)/denom;
	ip.y=(a2*c1 - a1*c2)/denom;
 
	//---------------------------------------------------
	//Do checks to see if intersection to endpoints
	//distance is longer than actual Segments.
	//Return null if it is with any.
	//---------------------------------------------------
	if(as_seg){
		if(Point.distance(ip,B) > Point.distance(A,B)){
			return null;
		}
		if(Point.distance(ip,A) > Point.distance(A,B)){
			return null;
		}	
 
		if(Point.distance(ip,F) > Point.distance(E,F)){
			return null;
		}
		if(Point.distance(ip,E) > Point.distance(E,F)){
			return null;
		}
	}
	return ip;
}

This entry was posted on Monday, August 4th, 2008 at 12:07 am and is filed under ActionScript 3, Flash 9.You can follow any responses to this entry through the RSS 2.0 feed. You can leave a response, or trackback from your own site.

12 Responses to “Find Intersection Point of two lines in AS3”

Keith Hair » Line to Polygon intersection data says: August 10th, 2008 at 4:09 am

[...] uses the “lineIntersectLine” function of the earlier [...]
James says: October 23rd, 2008 at 5:19 am

Thanks Keith, for the solution. Saved my time.
trilok says: December 30th, 2008 at 2:59 am

thanks kaith for this solution i was thinking on this thing from last few days u help me so much
Shiyaz says: February 5th, 2009 at 8:05 am

Thanks Keith, that is a nice one. Any thoughts on intersection of *rotated* lines? The example here considers that the planes of both the lines are same. What will happen if any one or both the lines are rotated? How to get the intersection in that case? Any help will be much appreciated. ~ Shiyaz
Keith H says: February 6th, 2009 at 12:28 am

Shiyaz,

This link might be helpful on the subject of planes and intersections. It has C++ implementations and pseudo code to help make it easier to create an AS3 implementation or into some other language, hope it helps.

http://softsurfer.com/Archive/algorithm_0104/algorithm_0104B.htm
Shiyaz says: February 16th, 2009 at 9:20 am

Thanks Keith. The links were helpful. I required the intersections of rotating planes to find the reflection of a point across a moving mirror line. However, the links threw more light on the concept. I did solve my problem by using *midpoint formula* approach. Would share the pseudo code after some cleanup. ~ Shiyaz
trop bien le blog » triangulation de polygones concaves et convexes says: February 26th, 2009 at 11:57 am

[...] sources sinon: la fonction d’intersection de segments vient de chez Keith Hair: http://keith-hair.net/blog/2008/08/04/find-intersection-point-of-two-lines-in-as3/ on doit pouvoir accélérer le test sur les segment notes [...]
HIDIHO! » concave shape triangulation: ear cutting algorithm says: March 5th, 2009 at 8:44 am

[...] the way: the segment intersection function comes from Keith Hair’s blog (pretty nice job ): http://keith-hair.net/blog/2008/08/04/find-intersection-point-of-two-lines-in-as3/ I think something can be done to accelerate the ‘as_seg’ section [...]
Robert Boyd says: April 9th, 2009 at 1:47 am

Thanks a million.
Rob McCardle says: May 8th, 2009 at 12:29 pm

This was really useful, thanks a million
Controul > A quick note on line and segment intersection (as3) says: May 9th, 2009 at 2:15 pm

[...] intersections that have saved me more than a few hours of headbanging. In particular, his line intersection function is a marvelous paste-and-go solution, and I really feel like posting a small optimisation that [...]
takopus says: July 3rd, 2009 at 7:05 am

Thank you!

Scripting is fun like any other hobby

Find Intersection Point of two lines in AS3