Example 1

trace(getIncrementFilePath("gallery/image01.png")); //returns gallery/image02.png

Example 2
Creating incremented filepaths in a loop.

var path:String="gallery/image01.png";

var i:int=0;
while (i < 10)
{
	path=getIncrementFilePath(path);
	trace(path);
	i++;
}

/*
trace output
===================
gallery/image02.png
gallery/image03.png
gallery/image04.png
gallery/image05.png
gallery/image06.png
gallery/image07.png
gallery/image08.png
gallery/image09.png
gallery/image10.png
gallery/image11.png
*/

The source

/**
 * Gets a new filepath with incremented digits .
 *
 * @param filepath The filepath to get an incremented filepath from.
 * @param incrementPrefix If true, any digit prefixes will be incremented in the filepath. This is false by default.
 * @param incrementSuffix If true, any digit suffixes will be incremented in the filepath. This is true by default.
 * @return A filepath with the filename's digit suffix or prefix incremented.
 * Returns an empty String if there are no numbers to increment.
 **/
function getIncrementFilePath(filepath:String="",incrementPrefix:Boolean=false,incrementSuffix:Boolean=true):String
{
	var s:String="";
	var bre:RegExp=/^\d+/mig;
	var ere:RegExp=/\d+$/mig;
	var dpath:String=(filepath.match(/^.+\//mig)[0])||"";
	var fs:String=filepath.replace(/^.+(\/|\\)/mig,"");
	var ext:String=fs.replace(/^.+\./mig,"");
	var fn:String=fs.replace(/\.\w+$/mig,"");
	var bd:String=(fn.match(bre))[0]||"";
	var ed:String=(fn.match(ere))[0]||"";
	var mids:String=fn.replace(bre,"").replace(ere,"");
	var md:String=mids.replace(/^[^\d]+|[^\d]+$/mig,"");
	var dlen:int;
	var tempstr:String="";
	var tempn:int;
	var n:int=0;
	if (incrementPrefix)
	{
		if (bd == "")
		{
			return "";
		}
		dlen=String((bd.match(/^0+/mig)[0])||"").length;
		tempn=parseInt(bd)+1;
		while (n < dlen)
		{
			tempstr+="0";
			n++;
		}
		if (String(tempstr+tempn).length > bd.length)
		{
			tempstr=tempstr.substr(1,tempstr.length);
		}
		bd=tempstr+tempn;
	}
	if (incrementSuffix)
	{
		if (ed == "")
		{
			return "";
		}
		dlen=String((ed.match(/^0+/mig)[0])||"").length;
		tempn=parseInt(ed)+1;
		while (n < dlen)
		{
			tempstr+="0";
			n++;
		}
		if (String(tempstr+tempn).length > ed.length)
		{
			tempstr=tempstr.substr(1,tempstr.length);
		}
		ed=tempstr+tempn;
	}
	if (ext != "")
	{
		ext="."+ext;
	}
	s=dpath+bd+mids+ed+ext;
	return s;
}

Dana Barrett: Are you the Keymaster?
Dr. Peter Venkman: Yes. Actually I'm a friend of his, he asked me to meet him here.
-Ghostbusters

It's been a whole year since I needed to use the KeyManager class and from comments I've been made aware of bugs in my script.
I was hoping the scripts would be a sufficient start that should issues arrive, others would come up with work-a-rounds. (Thank you to all who noted solutions and problems.)

Lately I was needing to write some keyboard interactivity again and I wanted to add some features to help simplify newer task...also fix a couple of things in the process.
In Flex, a lot of coding deals with listening to events. The KeyManager needed events for the tasks I was working on. Callback functions where ok at first but adding "KEY_DOWN", "KEY_UP" and "KEY_SEQUENCE" events help make the class more useful for monitoring status. Monitoring events give more options for handling keyboard activity in one handler function versus using a separate function for each keyboard combination. So now I've updated the class to have both.

This is a simple example of using the KeyManager class with the added features and KeyManagerEvent.
The example application displays the key activity as you press assigned keys. The functions executed should give a simple idea of how you could expand and add your own application/game logic.

The KeyManager is written for Flex and AS3 only projects.
I decided to share this class since it solves my current task, but I know it is not a solution for everything. Feel free to comment on it's issues or what's needed.
View Source

When an app or game is written we "expect" the user to precisely press the proper key or key combination at a time to execute programmatic actions. However, most of us have ten fingers and we use more than one finger to press more than one button on the keyboard. The expected program reaction from multiple fingered keyboard input might not occur because you have another function executing when you expect just one at a time.

Key Combinations
Imagine you are using the keyboard to play a game. The RIGHT arrow key is for moving your character right, the LEFT arrow key is for moving your character LEFT.
Ok, the action in this game is heating up, you are pressing LEFT to avoid the lasers shooting at you. You successfully dodged the lasers, now you press RIGHT to move in and attack...but in the heat of battle, your other finger is still on the LEFT button. What happens now is your character most likely gets stuck, because both movement keys are pressed telling the character to go in opposite directions!

In some cases allowing multiple key presses is how you want the app to react. For example you want the user to press both UP and RIGHT keys to move the characters in a diagonal direction. When to allow this and when not can be different among all of the control buttons. It becomes messy having to write "If" and "switch" statements to make the KeyboardEvent listeners work according to the different controls needed.

Key Sequences
If you love video games cheats or the easter eggs developers sometimes place in apps you'll remember to access them, you will usually enter in a sequence of key presses. If you entered the sequence successfully you would have access to cool game cheats or some special developer mode of an application.

KeyManager
For the above reasons I've written a KeyManager class to add key control that allows individual keys/keycombos the option to cancel out the any previous key/keycombo that are pressed down...and when key/keycombos are released, whatever key/keycombo that are still pressed will be active again. And for detecting key press sequences the KeyManager class will allow also.

This is a basic example using KeyManager. The "addKey" method is for adding key press combos and the "addKeySequence" is for obviously adding
key press sequences.

In the working flash example, you can click "singular combos" checkbox to false, to see the problem described previously about the character getting stuck when pressing RIGHT and LEFT key at the same time. When you set the checkbox back to true you will notice how each new key press overrides any others that are still down. This results in responsive execution if a user has a habit of holding down other keys while pressing new ones..

Also in the working sample above if you enter in the proper key sequence you will be rewarded with an "Easter Egg" to view the source and FLA.

Example usage:

import net.keithhair.KeyManager;

var keyManager:KeyManager;
keyManager=new KeyManager(stage);
keyManager.addKey(["right"], goRight,stopRight,"control1");
keyManager.addKey(["left"], goLeft,stopLeft,"control2");
keyManager.addKey(["up"], goUp,stopUp,"control3");
keyManager.addKey(["down"], goDown,stopDown,"control4");
keyManager.addKey(["shift","w","t"], toggleWindow);
keyManager.addKeySequence(["up","up","down","down","left","right","left","right"],openEasterEgg);

In my AIR application I have other AIR Windows floating over the main AIR Window.
I wanted one of my UIComponents to be draggable like a cursor, but when my mouse dragged the object
over the other floating windows I wanted my original cursor to show again and hide my dragged UIComponent.

The reason behind this is if I wanted to apply "context sensitive" behaviors depending on what or which window the mouse is in.

To do this, the main WindowedApplication needed some ROLL_OUT and ROLL_OVER events added to it to detect when the mouse rolls in and out.
The "getAIRAppWindow" method below finds the main WindowedApplication so I can add the listeners to it from there.

Here are some snippets explaining what I did:

The method needed to find main WindowedApplication

 
/*----------------------------------------------------------
Finds the main WindowedApplication of an AIR application
from any UIComponent and returns it.
------------------------------------------------------------*/
public function getAIRAppWindow(p:DisplayObjectContainer):WindowedApplication
{
	var c:*=p;
	while(c.parent){
		if(c is WindowedApplication){
					return WindowedApplication(c);
				}
			c=c.parent;
		}
	return null;
}
 

Adding events to detect mouse in main Windowed Application

 
_windowedApp=getAIRAppWindow(parent);
 
_windowedApp.addEventListener(MouseEvent.ROLL_OUT,__onMouseOutWorkSpace);
_windowedApp.addEventListener(MouseEvent.ROLL_OVER,__onMouseInWorkSpace);
 

Example of actions to apply on ROLL_OUT and ROLL_OVER

 
private function __onMouseOutWorkSpace(evt:MouseEvent):void
{
	/*--------------------------------------------------------
	When your mouse rolls out of the main WindowedApplication
	(and into other nested Windows) you can make your regular
	mouse cursor show again here, while hiding your custom cursor.
	----------------------------------------------------------*/
	yourCustomCursor.visible=false;
	Mouse.show();
}
private function __onMouseInWorkSpace(evt:MouseEvent):void
{
	/*--------------------------------------------------------
	When your mouse rolls back in the main WindowedApplication
	(and out of other nested Windows) you can hide your regular
	mouse cursor, while showing your custom cursor again.
	----------------------------------------------------------*/
	yourCustomCursor.visible=true;
	Mouse.hide();
}