If you played the first installment of Half-Life 2, you may remember the NPC characters frequently shouting "Follow Freeman".
As the NPC characters stood around idle, they would make comments that sound as if they where on Twitter. LOL

Way back when the original Half-Life game came out and I played it on my ancient 3Dfx Voodoo card, the graphics blew me away. I've been loving the whole Half Life series and wait in anticipation for the next episode.
I was disappointed that there was not much news of Half-Life 2 Episode 3 this year, so lately I been going back into time to enjoy the beginning of Half Life 2. I thought Half-Life 1 set the bar.
This game set the bar again, the experience is so well done, that the replay value is good even for single player mode. I have lots PC games, once I finish one, I uninstall it. This is one of the few games I have worthy of staying installed for years.

The "whereAboutSegment" function will return a String this time, with more detailed info of the Point's where-a-abouts instead of just knowing if its behind a line.

 
/*-----------------------------------------------------------------
Returns a String describing where Point P is relevant to line CD:
"left","right","front" or "behind"
If Point P is a Point on line CD, an empty String is returned.
 ----------------------------------------------------------------*/
function whereAboutSegment(P:Point,C:Point,D:Point):String
{
	var F:Point;
	var G:Point;
	var s:Boolean;
	var l:Boolean;
	var r:Boolean;
	var f:Boolean;
	var a:Number=Point.distance(P,C.add(Point.polar(1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI / 2)));
	var b:Number=Point.distance(P,C.add(Point.polar(-1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI / 2)));
	s = a == b;
	if (a < b) {
		f=true;
	}
	F=C.add(Point.polar(1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI));
	G=C.add(Point.polar(-1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI));
	a=Point.distance(P,F.add(Point.polar(1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI)));
	b=Point.distance(P,G.add(Point.polar(-1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI)));
	if (a < b) {
		r=true;
	}
	F=D.add(Point.polar(1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI));
	G=D.add(Point.polar(-1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI));
	a=Point.distance(P,F.add(Point.polar(1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI )));
	b=Point.distance(P,G.add(Point.polar(-1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI)));
	if (a > b) {
		l=true;
	}
	if (s && l && r) {
		return "";
	}
	if (!f && l && r) {
		return "behind";
	}
	if (f && l && r) {
		return "front";
	}
	if (l) {
		return "left";
	}
	if (r) {
		return "right";
	}
	return "";
}
 

I had a similar problem also with my scripts. I wanted to simply know if a Point was behind a Line or not...

 
/*-----------------------------------------------------------------
Returns true if Point P is behind line defined by Points C and D.
 ----------------------------------------------------------------*/
function isBehindLine(P:Point,C:Point,D:Point):Boolean
{
	var a:Number=Point.distance(P,C.add(Point.polar(1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI / 2)));
	var b:Number=Point.distance(P,C.add(Point.polar(-1,Math.atan2(C.y - D.y,C.x - D.x) + Math.PI / 2)));
	return a < b;
}
 

 
 
/*---------------------------------------------------------------------------
Returns Array of intersection Points on a quadratic curve.
An empty Array is returned if no intersection is found.
 
Parameters:
A		-Start Point of a segment to make intersection.
B		-End Point of a segment to make intersection.
sp		-Start Point of curve.
cp		-Control Point of curve.
ep		-End Point of curve.
rez		-The resolution of curve tests
Note: Uses another function for testing the intersections:
http://keith-hair.net/blog/2008/08/04/find-intersection-point-of-two-lines-in-as3/
----------------------------------------------------------------------------*/
function lineToQCurve_Intersect(A:Point,B:Point,sp:Point,cp:Point,ep:Point,rez:Number=80):Array
{
	//rez less than 2 is almost "Pointless" LOL.
	var low:Number=2;
	var high:Number=99; //100 causes infinite loop.
	rez=Math.min(Math.max(Math.min(low,high),rez),high);
	var t:Number=0;
	var ft:Number=0;
	var n:Number=99/rez;
	var C:Point=new Point();
	var D:Point=new Point();
	var L:Point=new Point();
	var ip:Point;
	var a:Array=[];
	//test possible segment intersections in a loop.
	var z:int=100;
	while (z > -1)
	{
		t=z/100;
		C.x=Math.pow(1-t,2)*sp.x+2*(1-t)*t*cp.x+Math.pow(t,2)*ep.x;
		C.y=Math.pow(1-t,2)*sp.y+2*(1-t)*t*cp.y+Math.pow(t,2)*ep.y;
		D=L;//Connect start to last end point
		L=C.clone();
		if (z == 100) {
			D=ep.clone();
		}
		ip=lineIntersectLine(A,B,C,D);
		if (ip != null) {
			a.push(ip);
			if(a.length == 2){
				break;
			}
		}
		z-=n;
	}
	return a;
}
 

In my AIR application I have other AIR Windows floating over the main AIR Window.
I wanted one of my UIComponents to be draggable like a cursor, but when my mouse dragged the object
over the other floating windows I wanted my original cursor to show again and hide my dragged UIComponent.

The reason behind this is if I wanted to apply "context sensitive" behaviors depending on what or which window the mouse is in.

To do this, the main WindowedApplication needed some ROLL_OUT and ROLL_OVER events added to it to detect when the mouse rolls in and out.
The "getAIRAppWindow" method below finds the main WindowedApplication so I can add the listeners to it from there.

Here are some snippets explaining what I did:

The method needed to find main WindowedApplication

 
/*----------------------------------------------------------
Finds the main WindowedApplication of an AIR application
from any UIComponent and returns it.
------------------------------------------------------------*/
public function getAIRAppWindow(p:DisplayObjectContainer):WindowedApplication
{
	var c:*=p;
	while(c.parent){
		if(c is WindowedApplication){
					return WindowedApplication(c);
				}
			c=c.parent;
		}
	return null;
}
 

Adding events to detect mouse in main Windowed Application

 
_windowedApp=getAIRAppWindow(parent);
 
_windowedApp.addEventListener(MouseEvent.ROLL_OUT,__onMouseOutWorkSpace);
_windowedApp.addEventListener(MouseEvent.ROLL_OVER,__onMouseInWorkSpace);
 

Example of actions to apply on ROLL_OUT and ROLL_OVER

 
private function __onMouseOutWorkSpace(evt:MouseEvent):void
{
	/*--------------------------------------------------------
	When your mouse rolls out of the main WindowedApplication
	(and into other nested Windows) you can make your regular
	mouse cursor show again here, while hiding your custom cursor.
	----------------------------------------------------------*/
	yourCustomCursor.visible=false;
	Mouse.show();
}
private function __onMouseInWorkSpace(evt:MouseEvent):void
{
	/*--------------------------------------------------------
	When your mouse rolls back in the main WindowedApplication
	(and out of other nested Windows) you can hide your regular
	mouse cursor, while showing your custom cursor again.
	----------------------------------------------------------*/
	yourCustomCursor.visible=true;
	Mouse.hide();
}
 

One thing that bothers me is that I could not figure out how to skew along the X and Y axis at the same time. When I do set "c" and "b" Matrix properties, one of the skewed axis does not skew parallel like it should. And if I concatenate separate skew Matrices, the last concatenated skew Matrix transforms correctly but not the one before it. I'm trying to avoid using nested DisplayObjects to perform the separate X and Y skews, but that looks like an option I will have to use.

 
/*---------------------------------------------------------------------------
Sets the transform property of DisplayObject with a customized Matrix.
 
display			-An ActionScript DisplayObject.
tx					-Translation x.
ty					-Translation y.
reg				-Registation point from which all transform effects orient from.
ang				-Rotation in in degrees.
scalex				-X scale percentage.
scaley				-Y scale percentage.
skew				-Skew percentage of the DisplayObjects width or height.
axis				-String indicating which axis to skew on.
 
Note:	-The "skew" argument only works one axis at a time, If anyone knows
		 how to skew on both X and Y axis at the same time accurately please help me.
 
		-The "reg" Registration point get scaled by scalex and scaley.		 
 
----------------------------------------------------------------------------*/
function setDisplayMatrix(display:DisplayObject,
						  tx:Number=0,
						  ty:Number=0,
						  reg:Point=null,
						  ang:Number=0,
						  scalex:Number=1,
						  scaley:Number=1,
						  skew:Number=0,
						  axis:String="x"):void
{
	reg=reg||new Point();
	var curM:Matrix=new Matrix();
	var skewM:Matrix=new Matrix();
	var rotM:Matrix=new Matrix();
	var scaleM:Matrix=new Matrix();
	var rp:Point;
	var r:Number=ang*Math.PI/180;
	if(axis == "y"){
		skewM.c=Math.tan(skew);
	}else{
		skewM.b=Math.tan(skew);
	}
	scaleM.scale(scalex,scaley);
	rotM.rotate(r);
	curM.concat(scaleM);
	curM.concat(skewM);
	curM.concat(rotM);
	rp=curM.transformPoint(reg);
	curM.tx=-rp.x;
	curM.ty=-rp.y;
	curM.tx+=tx;
	curM.ty+=ty;
	display.transform.matrix=curM;
}
 

Here is a diagram I made to show what kind of skew I wanted to achieve instead of only skewing one axis at a time:

 
/*---------------------------------------------------------------------------
Returns the closest Point on Line "AB" to Point "p":
 
p			-Point, the Point to constrain to the line.
A			-Point, beginning Point of Line.
B			-Point, ending Point of Line.
as_seg	-Boolean, limits return Point between endpoints of A and B.
----------------------------------------------------------------------------*/
function constrainPointToLine(p:Point,A:Point,B:Point,as_seg:Boolean=false):Point
{
    var cp:Point=new Point();
    var dx:Number;
    var dy:Number;
    var t:Number;
 
    dx = B.x - A.x;
    dy = B.y - A.y;
    if (dx == 0 && dy == 0) {
        cp.x = A.x;
        cp.y = A.y;
    }else{
        t = ((p.x - A.x) * dx + (p.y - A.y) * dy) / (dx * dx + dy * dy);
        if (as_seg){
			t = Math.min(Math.max(0,t),1);
		}
        cp.x = A.x + t * dx;
        cp.y = A.y + t * dy;
    }
    return cp;
}
 

I like to have this same ability when I'm writing ActionScript to resize objects proportionately too.
Here I use the functions to set the sizes so when I set width, height is changed accordingly.
The same for setting height, the width is changed accordingly.

*Note: I set the inputs to limit the width and height to 500.

Here are two functions for performing proportional resizing by both width and height...

/*---------------------------------------------
Resize proportionately by width.
Returns an Object with new proportionate "width" and "height" properties.
After passing the current width, current height and  a new width.
-----------------------------------------------*/
function constrainSizeToWidth(oldW:Number,oldH:Number,newW:Number):Object
{
	return {width:newW,height:newW / oldW * oldH};
}
 
/*---------------------------------------------
Resize proportionately by height.
Returns an Object with new proportionate "width" and "height" properties.
After passing the current width, current height and  a new height.
-----------------------------------------------*/
function constrainSizeToHeight(oldW:Number,oldH:Number,newH:Number):Object
{
	return {width:newH / oldH * oldW,height:newH};
}
 

This uses the "lineIntersectLine" function of the earlier post.

 
/*---------------------------------------------------------------------------
Returns an Object with the following properties:
intersects        -Boolean indicating if an intersection exists.
start_inside      -Boolean indicating if Point A is inside of the polygon.
end_inside       -Boolean indicating if Point B is inside of the polygon.
intersections    -Array of intersection Points along the polygon.
centroid          -A Point indicating "center of mass" of the polygon.
 
"pa" is an Array of Points.
----------------------------------------------------------------------------*/
function lineIntersectPoly(A : Point, B : Point, pa:Array):Object {
	var An:int=1;
	var Bn:int=1;
	var C:Point;
	var D:Point;
	var i:Point;
	var cx:Number=0;
	var cy:Number=0;
	var result:Object = new Object();
	pa.push(pa[0]);
	result.intersects = false;
	result.intersections=[];
	result.start_inside=false;
	result.end_inside=false;
	var n:int=pa.length-1;
	while(n > -1){
		C=Point(pa[n]);
		if(n > 0){
			cx+=C.x;
			cy+=C.y;
			D=Point(pa[n-1])||Point(pa[0]);
			i=lineIntersectLine(A,B,C,D);
			if(i != null){
				result.intersections.push(i);
			}
			if(lineIntersectLine(A,new Point(C.x+D.x,A.y),C,D) != null){
				An++;
			}
			if(lineIntersectLine(B,new Point(C.x+D.x,B.y),C,D) != null){
				Bn++;
			}
		}
		n--;
	}
	if(An % 2 == 0){
		result.start_inside=true;
	}
	if(Bn % 2 == 0){
		result.end_inside=true;
	}
	result.centroid=new Point(cx/(pa.length-1),cy/(pa.length-1));
	result.intersects = result.intersections.length > 0;
	return result;
}